Mojo::IOLoop - Minimalistic event loop
use Mojo::IOLoop;
# Listen on port 3000
Mojo::IOLoop->server({port => 3000} => sub ($loop, $stream, $id) {
$stream->on(read => sub ($stream, $bytes) {
# Process input chunk
say $bytes;
# Write response
$stream->write('HTTP/1.1 200 OK');
});
});
# Connect to port 3000
my $id = Mojo::IOLoop->client({port => 3000} => sub ($loop, $err, $stream) {
$stream->on(read => sub ($stream, $bytes) {
# Process input
say "Input: $bytes";
});
# Write request
$stream->write("GET / HTTP/1.1\x0d\x0a\x0d\x0a");
});
# Add a timer
Mojo::IOLoop->timer(5 => sub ($loop) { $loop->remove($id) });
# Start event loop if necessary
Mojo::IOLoop->start unless Mojo::IOLoop->is_running;
the Mojo::IOLoop manpage is a very minimalistic event loop based on the Mojo::Reactor manpage, it has been reduced to the absolute
minimal feature set required to build solid and scalable non-blocking clients and servers.
Depending on operating system, the default per-process and system-wide file descriptor limits are often very low and
need to be tuned for better scalability. The LIBEV_FLAGS environment variable should also be used to select the best
possible EV backend, which usually defaults to the not very scalable select.
LIBEV_FLAGS=1 # select
LIBEV_FLAGS=2 # poll
LIBEV_FLAGS=4 # epoll (Linux)
LIBEV_FLAGS=8 # kqueue (*BSD, OS X)
LIBEV_FLAGS=64 # Linux AIO
The event loop will be resilient to time jumps if a monotonic clock is available through the Time::HiRes manpage. A TLS
certificate and key are also built right in, to make writing test servers as easy as possible. Also note that for
convenience the PIPE signal will be set to IGNORE when the Mojo::IOLoop manpage is loaded.
For better scalability (epoll, kqueue) and to provide non-blocking name resolution, SOCKS5 as well as TLS support, the
optional modules EV (4.32+), the Net::DNS::Native manpage (0.15+), the IO::Socket::Socks manpage (0.64+) and the IO::Socket::SSL manpage
(2.009+) will be used automatically if possible. Individual features can also be disabled with the MOJO_NO_NNR,
MOJO_NO_SOCKS and MOJO_NO_TLS environment variables.
See REAL-TIME WEB in the Mojolicious::Guides::Cookbook manpage for more.
the Mojo::IOLoop manpage inherits all events from the Mojo::EventEmitter manpage and can emit the following new ones.
$loop->on(finish => sub ($loop) {...});
Emitted when the event loop wants to shut down gracefully and is just waiting for all existing connections to be
closed.
$loop->on(reset => sub ($loop) {...});
Emitted when the event loop is reset, this usually happens after the process is forked to clean up resources that
cannot be shared.
the Mojo::IOLoop manpage implements the following attributes.
my $max = $loop->max_accepts;
$loop = $loop->max_accepts(1000);
The maximum number of connections this event loop is allowed to accept, before shutting down gracefully without
interrupting existing connections, defaults to 0. Setting the value to 0 will allow this event loop to accept new
connections indefinitely. Note that up to half of this value can be subtracted randomly to improve load balancing
between multiple server processes, and to make sure that not all of them restart at the same time.
my $max = $loop->max_connections;
$loop = $loop->max_connections(100);
The maximum number of accepted connections this event loop is allowed to handle concurrently, before stopping to accept
new incoming connections, defaults to 1000.
my $reactor = $loop->reactor;
$loop = $loop->reactor(Mojo::Reactor->new);
Low-level event reactor, usually a the Mojo::Reactor::Poll manpage or the Mojo::Reactor::EV manpage object with a default subscriber to
the event error in the Mojo::Reactor manpage.
# Watch if handle becomes readable or writable
Mojo::IOLoop->singleton->reactor->io($handle => sub ($reactor, $writable) {
say $writable ? 'Handle is writable' : 'Handle is readable';
});
# Change to watching only if handle becomes writable
Mojo::IOLoop->singleton->reactor->watch($handle, 0, 1);
# Remove handle again
Mojo::IOLoop->singleton->reactor->remove($handle);
the Mojo::IOLoop manpage inherits all methods from the Mojo::EventEmitter manpage and implements the following new ones.
my $server = Mojo::IOLoop->acceptor($id);
my $server = $loop->acceptor($id);
my $id = $loop->acceptor(Mojo::IOLoop::Server->new);
Get the Mojo::IOLoop::Server manpage object for id or turn object into an acceptor.
my $id = Mojo::IOLoop->client(address => '127.0.0.1', port => 3000, sub {...});
my $id = $loop->client(address => '127.0.0.1', port => 3000, sub {...});
my $id = $loop->client({address => '127.0.0.1', port => 3000} => sub {...});
Open a TCP/IP or UNIX domain socket connection with the Mojo::IOLoop::Client manpage and create a stream object (usually
the Mojo::IOLoop::Stream manpage), takes the same arguments as connect in the Mojo::IOLoop::Client manpage.
my $bool = Mojo::IOLoop->is_running;
my $bool = $loop->is_running;
Check if event loop is running.
my $undef = Mojo::IOLoop->next_tick(sub ($loop) {...});
my $undef = $loop->next_tick(sub ($loop) {...});
Execute callback as soon as possible, but not before returning or other callbacks that have been registered with this
method, always returns undef.
# Perform operation on next reactor tick
Mojo::IOLoop->next_tick(sub ($loop) {...});
Mojo::IOLoop->one_tick;
$loop->one_tick;
Run event loop until an event occurs.
# Don't block longer than 0.5 seconds
my $id = Mojo::IOLoop->timer(0.5 => sub ($loop) {});
Mojo::IOLoop->one_tick;
Mojo::IOLoop->remove($id);
my $id = Mojo::IOLoop->recurring(3 => sub ($loop) {...});
my $id = $loop->recurring(0 => sub ($loop) {...});
my $id = $loop->recurring(0.25 => sub ($loop) {...});
Create a new recurring timer, invoking the callback repeatedly after a given amount of time in seconds.
# Perform operation every 5 seconds
Mojo::IOLoop->recurring(5 => sub ($loop) {...});
Mojo::IOLoop->remove($id);
$loop->remove($id);
Remove anything with an id, connections will be dropped gracefully by allowing them to finish writing all data in their
write buffers.
Mojo::IOLoop->reset;
$loop->reset;
$loop->reset({freeze => 1});
Remove everything and stop the event loop.
These options are currently available:
- freeze
-
freeze => 1
Freeze the current state of the event loop in time before resetting it. This will prevent active connections from
getting closed immediately, which can help with many unintended side effects when processes are forked. Note that this
option is EXPERIMENTAL and might change without warning!
my $id = Mojo::IOLoop->server(port => 3000, sub {...});
my $id = $loop->server(port => 3000, sub {...});
my $id = $loop->server({port => 3000} => sub {...});
Accept TCP/IP and UNIX domain socket connections with the Mojo::IOLoop::Server manpage and create stream objects (usually
the Mojo::IOLoop::Stream manpage, takes the same arguments as listen in the Mojo::IOLoop::Server manpage.
# Listen on random port
my $id = Mojo::IOLoop->server({address => '127.0.0.1'} => sub ($loop, $stream, $id) {...});
my $port = Mojo::IOLoop->acceptor($id)->port;
my $loop = Mojo::IOLoop->singleton;
The global the Mojo::IOLoop manpage singleton, used to access a single shared event loop object from everywhere inside the
process.
# Many methods also allow you to take shortcuts
Mojo::IOLoop->timer(2 => sub { Mojo::IOLoop->stop });
Mojo::IOLoop->start;
# Restart active timer
my $id = Mojo::IOLoop->timer(3 => sub { say 'Timeout!' });
Mojo::IOLoop->singleton->reactor->again($id);
# Turn file descriptor into handle and watch if it becomes readable
my $handle = IO::Handle->new_from_fd($fd, 'r');
Mojo::IOLoop->singleton->reactor->io($handle => sub ($reactor, $writable) {
say $writable ? 'Handle is writable' : 'Handle is readable';
})->watch($handle, 1, 0);
Mojo::IOLoop->start;
$loop->start;
Start the event loop, this will block until stop is called. Note that some reactors stop automatically if there
are no events being watched anymore.
# Start event loop only if it is not running already
Mojo::IOLoop->start unless Mojo::IOLoop->is_running;
Mojo::IOLoop->stop;
$loop->stop;
Stop the event loop, this will not interrupt any existing connections and the event loop can be restarted by running
start again.
Mojo::IOLoop->stop_gracefully;
$loop->stop_gracefully;
Stop accepting new connections and wait for already accepted connections to be closed, before stopping the event loop.
my $stream = Mojo::IOLoop->stream($id);
my $stream = $loop->stream($id);
my $id = $loop->stream(Mojo::IOLoop::Stream->new);
Get the Mojo::IOLoop::Stream manpage object for id or turn object into a connection.
# Increase inactivity timeout for connection to 300 seconds
Mojo::IOLoop->stream($id)->timeout(300);
my $subprocess = Mojo::IOLoop->subprocess;
my $subprocess = $loop->subprocess;
my $subprocess = $loop->subprocess(sub ($subprocess) {...}, sub ($subprocess, $err, @results) {...});
Build the Mojo::IOLoop::Subprocess manpage object to perform computationally expensive operations in subprocesses, without
blocking the event loop. Callbacks will be passed along to run in the Mojo::IOLoop::Subprocess manpage.
# Operation that would block the event loop for 5 seconds
Mojo::IOLoop->subprocess->run_p(sub {
sleep 5;
return '♥', 'Mojolicious';
})->then(sub (@results) {
say "I $results[0] $results[1]!";
})->catch(sub ($err) {
say "Subprocess error: $err";
});
my $id = Mojo::IOLoop->timer(3 => sub ($loop) {...});
my $id = $loop->timer(0 => sub ($loop) {...});
my $id = $loop->timer(0.25 => sub ($loop) {...});
Create a new timer, invoking the callback after a given amount of time in seconds.
# Perform operation in 5 seconds
Mojo::IOLoop->timer(5 => sub ($loop) {...});
You can set the MOJO_IOLOOP_DEBUG environment variable to get some advanced diagnostics information printed to
STDERR.
MOJO_IOLOOP_DEBUG=1
Mojolicious, the Mojolicious::Guides manpage, https://mojolicious.org.
|